import QtQuick 2.0
import QtQuick.Controls 2.4

/**
 * @brief Navigation view containing list view displaying artists or genres and albums
 */
Item {
    id: container
    property int margins: StyleMargins.defaultMargin
    RoundImageButton{
        id: back

        anchors.top: parent.top
        anchors.left: parent.left
        anchors.margins: container.margins

        visible: navigationList.pIsBackVisible

        onClicked: navigationList.navigateBack();
    } // MyRoundButton: navigate back

    RoundImageButton{
        id: closeApp
        anchors.right: parent.right
        anchors.top: parent.top
        anchors.margins: container.margins
        visible: uiStateModel.pShowQuitAppButton
        imageSource: "qrc:/icon_close"
        onClicked: {
            Qt.quit();
        }
    } // MyRoundButton: closeApp

    Rectangle{
        anchors.left: parent.left
        anchors.right: parent.right
        anchors.verticalCenter: parent.verticalCenter

        height: StyleSizes.navigationListHeight

        color: "#99ffffff"

        Label{
            text: debug.pDebugOutput
            anchors.centerIn: parent
            visible: text !== ""
        }

        ListView{
            id: circleList
            anchors.left: parent.left
            anchors.right: parent.right
            anchors.verticalCenter: parent.verticalCenter
            anchors.margins: StyleMargins.defaultMargin

            height: parent.height - 2*StyleMargins.defaultMargin

            model: navigationList.pModelItems
            spacing: StyleSpacings.defaultSpacing
            orientation: ListView.Horizontal
            delegate: NavigationListDelegate{
                id: delegate
                property var delegateModel: navigationList.pModelItems[index]
                height: parent.height
                width: height
                isCircleDelegate: delegateModel.pIsCircleDelegate
                imageSource: delegateModel.pImageSource
                onClicked: delegateModel.onClicked();
            } // NavigationListDelegate
        } // ListView
    } // Rectangle: List background
} // Item